<% Option Explicit %>
<!-- #include virtual = "inc/adovbs.inc" -->
<!-- #include virtual = "inc/database_connect.inc" -->
<%

Response.ContentType="application/rss+xml"
Response.Charset="iso-8859-1"

Function return_RFC822_Date(myDate, offset)

  Dim myDay, myDays, myMonth, myYear
  Dim myHours, myMinutes, mySeconds

  myDate = CDate(myDate)
  myDay = WeekdayName(Weekday(myDate),true)
  myDays = Day(myDate)
  myMonth = MonthName(Month(myDate), true)
  myYear = Year(myDate)
  myHours = zeroPad(Hour(myDate), 2)
  myMinutes = zeroPad(Minute(myDate), 2)
  mySeconds = zeroPad(Second(myDate), 2)

  return_RFC822_Date = myDay&", "& _
                       myDays&" "& _
                       myMonth&" "& _
                       myYear&" "& _
                       myHours&":"& _
                       myMinutes&":"& _
                       mySeconds&" "& _
                       offset
                       
End Function

Function zeroPad(m, t)

  zeroPad = String(t-Len(m),"0")&m

End Function

Function CleanText(charstring)

  Dim strFinalString
  Dim intLoop
  Dim intCharAscii
  
  For intLoop = 1 to Len(charstring)
  
    intCharAscii = Asc(Mid(charstring, intloop,1))
    
    If (intCharAscii >= 65 And intCharAscii <= 90) Or (intCharAscii >= 48 And intCharAscii <= 57) Or (intCharAscii >= 97 And intCharAscii <= 122) Or intCharAscii = 32 Or intCharAscii = 46 Then
    
      strFinalString = strFinalString & Mid(charstring, intloop,1)
    
    End If
    
  Next

  CleanText = strFinalString

End Function


'Page variables'

Dim intSectionID
Dim intSiteID
Dim strCompanyName
Dim strCompanyImage

Dim SQL

'Request posted values'

intSectionID = Request("id")
intSiteID = Request("siteid")

If intSectionID = "" Then intSectionID = 1 End If
If intSiteID = "" Then intSiteID = 1 End If


SQL =       "SELECT          TOP 20 [s].[viewtemplate], " & _
            "                [s].[section], " & _
            "                [s].[listtemplate], " & _
            "                [a].[id], " & _
            "                [a].[creationdate], " & _
            "                [a].[virtual], " & _
            "                [a].[virtualurl], " & _
            "                [a].[title], " & _
            "                [a].[teaser], " & _
            "                [a].[memberid], " & _
            "                [a2].[image3] AS 'companyimage', " & _
            "                [a].[image5], " & _
            "                [a].[price], " & _
            "                [a].[basecurrencyid], " & _
            "                [a2].[company], " & _
            "                [a2].[id] AS subsiteid, " & _
            "                [a].[displaypublishdate], " & _
            "                [a].[eventdatedisplay], " & _
            "                [a].[subsitedisplayonly], " & _
            "                [a].[publishdate], " & _
            "                [a].[eventdate] " & _
            "FROM            [so_article] [a] " & _
            "INNER JOIN      [so_article] [a2] ON [a].[memberid] = [a2].[id] AND [a2].[languageid] = 1 " & _
            "INNER JOIN      [so_section] [s] ON [a].[sectionid] = [s].[id] " & _
            "LEFT OUTER JOIN [so_article_shared] [as] " & _
            "ON              [a].[id] = [as].[articleid] " & _
            "AND             [as].[memberid] = " & intSiteID & " " & _
            "WHERE           [a].[languageid]= 1  " & _
            "AND             [a].[sectionid] = " & intSectionID & " " & _
            "AND             [a].[visible] = 1 " & _
            "AND             [a2].[staging] = 0 "

If CInt(intSiteID) > 1 Then

  SQL = SQL & "AND ([a].[memberid]=" & intSiteID & " OR [as].[id] > '') "

End If

SQL = SQL & "AND ([a2].[subsite] = 1 OR [a].[memberid] = 1) "

SQL = SQL & "ORDER BY [a].[creationdate] DESC"

objODBCCommand.CommandType = adCmdText

objODBCCommand.CommandText = SQL

Set objODBCRecSet = objODBCCommand.Execute

If Not objODBCRecSet.BOF Then

  If CInt(intSiteID) = 1 Then

    strCompanyName = "Fuel Cell Markets Ltd"
    strCompanyImage = "_--FCM-listings.gif"

  Else

    strCompanyImage = objODBCRecSet("companyimage")
    strCompanyName = objODBCRecSet("company")

  End If

%>
<?xml-stylesheet title="XSL_formatting" type="text/xsl" href="rss_fcm.xsl"?>
<rss version="2.0">
  <channel>
    <title><%=CleanText(strCompanyName)%> | <%=CleanText(objODBCRecSet("section"))%></title>
    <copyright>Copyright (C) 2006 <%=CleanText(strCompanyName)%>. All rights reserved.</copyright>
    <link><![CDATA[http://www.fuelcellmarkets.com/<%=objODBCRecSet("listtemplate")%>?section=<%=intSectionID%>&subsite=<%=intSiteID%>]]></link>
    <description>Latest <%=CleanText(objODBCRecSet("section"))%> information from <%=CleanText(strCompanyName)%></description>
    <language>en-us</language>
    <lastBuildDate><%=return_RFC822_Date(Now(), "GMT")%></lastBuildDate>
    <managingEditor>david.lockie@fuelcellmarkets.com</managingEditor>
    <webMaster>mike.williams@fuelcellmarkets.com</webMaster>
    <ttl>60</ttl>
    <image>
      <title><%=CleanText(strCompanyName)%> - <%=CleanText(objODBCRecSet("section"))%></title>
      <link><![CDATA[http://www.fuelcellmarkets.com/<%=objODBCRecSet("listtemplate")%>?section=<%=intSectionID%>&subsite=<%=intSiteID%>]]></link>
      <url>http://www.fuelcellmarkets.com/content/images/logos/<%=strCompanyImage%></url>
    </image>
<%

  Do While Not objODBCRecSet.EOF

%>
    <item>
      <title><%=CleanText(objODBCRecSet("title"))%></title>
      <link>http://www.fuelcellmarkets.com/<%=objODBCRecSet("viewtemplate")%>?articleid&#61;<%=objODBCRecSet("id")%>&#38;subsite&#61;<%=objODBCRecSet("memberid")%></link>
      <guid isPermaLink="true">http://www.fuelcellmarkets.com/<%=objODBCRecSet("viewtemplate")%>?articleid&#61;<%=objODBCRecSet("id")%>&#38;subsite&#61;<%=objODBCRecSet("memberid")%></guid>
      <pubDate><%=return_RFC822_Date(objODBCRecSet("creationdate"), "GMT")%></pubDate>
      <description><%=CleanText(objODBCRecSet("teaser"))%></description>
      <category>Fuel Cell &gt; <%=CleanText(objODBCRecSet("section"))%></category>
    </item>
<%

    objODBCRecSet.MoveNext

  Loop

%>
  </channel>
</rss>
<%

End If

%>